#!/usr/bin/mawk -We
# *********************************************************************
# totaltable: sums up selected table columns.
#
# Copyright (c) 2001,2006 Carlo Strozzi
#
# This program is free software; you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation; version 2 dated June, 1991.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
#
# *********************************************************************
#  $Id: totaltable,v 1.4 2006/03/10 11:26:13 carlo Exp $

BEGIN {
  NULL = ""; FS = OFS = "\t"; fmt = "%s"

  # Get local settings.
  nosql_install = ENVIRON["NOSQL_INSTALL"]
  stdout = ENVIRON["NOSQL_STDOUT"]
  stderr = ENVIRON["NOSQL_STDERR"]

  # Set default values if necessary.
  if (nosql_install == NULL) nosql_install = "/usr/local/nosql"
  if (stdout == NULL) stdout = "/dev/stdout"
  if (stderr == NULL) stderr = "/dev/stderr"

  while (ARGV[++i] != NULL) {
    if (ARGV[i] == "-l" || ARGV[i] == "--last") pick_last = 1
    else if (ARGV[i] == "-N" || ARGV[i] == "--no-header") no_hdr = 1
    else if (ARGV[i] == "-r" || ARGV[i] == "--report") report = 1
    else if (ARGV[i] == "-i" || ARGV[i] == "--input") i_file = ARGV[++i]
    else if (ARGV[i] == "-o" || ARGV[i] == "--output") o_file = ARGV[++i]
    else if (ARGV[i] == "-T" || ARGV[i] == "--total") gtcol = ARGV[++i]
    else if (ARGV[i] == "-t" || ARGV[i] == "--trim") trim = 1
    else if (ARGV[i] == "-s" || ARGV[i] == "--subtotal") stcols = ARGV[++i]
    else if (ARGV[i] == "-c" || ARGV[i] == "--currency") fmt = "%.3f"
    else if (ARGV[i] == "-h" || ARGV[i] == "--help") {
       system("grep -v '^#' " nosql_install "/help/totaltable.txt")
       exit(rc=1)
    }
    else if (ARGV[i] == "--show-copying") {
       system("cat " nosql_install "/doc/COPYING")
       exit(rc=1)
    }
    else if (ARGV[i] == "--show-warranty") {
       system("cat " nosql_install "/doc/WARRANTY")
       exit(rc=1)
    }
    else target_cols[ARGV[i]] = ARGV[i]
  }

  ARGC = 1					# Fix argv[]

  if (o_file == NULL) o_file = stdout
  if (i_file != NULL) { ARGV[1] = i_file; ARGC = 2 }

  stcols = "," stcols ","

  if (stcols != ",,") {
     gtcol = NULL				# override '-T'
     report = 1					# override '-r'
  }
}

#
# Main loop
#

NR == 1 {

  gsub(/\001/, "")			# Remove SOH markers

  gsub(/ +/,"")				# trim blanks in names.

  # Load the column position array.
  while (++p <= NF) {

    # Unless '-l' was specified, make sure we pick the first occurrence
    # of duplicated column names (it may happen after a join).

    if (pick_last) { P[$p] = p; N[p] = $p }
    else {
      if (P[$p] == NULL) { P[$p] = p; N[p] = $p }
    }
  }

  if (gtcol != NULL) $0 = $0 OFS gtcol
  if (!no_hdr) {
     printf("\001") > o_file; gsub(/\t/,"\t\001"); print > o_file
  }
  next
}

# Table body.
{
  for (i=1; i<=NF; i++) {
      if (NR > 2 && N[i] != NULL && stcols ~ N[i] && $i != V[N[i]]) {
	 st = 1
      }
      V[N[i]] = $i
  }

  if (gtcol != NULL) $0 = $0 OFS

  if (st) {
     print_subtotal()
     value = $0
     gsub(/[^\t]+/,NULL,value)
     print value > o_file		# print an empty row.
     delete total			# reset all totals.
     st = 0
  }

  for (i=1; i<=NF; i++) {
      if (target_cols[N[i]] != NULL && i == P[N[i]]) total[i] += $i
  }

  if (report) print > o_file
}

END {
  if (rc) exit(rc)
  print_subtotal()
}

function print_subtotal(		i,value,dashes) {

  for (i=1; i<=NF; i++) {
      if (i > 1) value = value OFS
      if (target_cols[N[i]] != NULL && i == P[N[i]]) {
	 if (gtcol != NULL) gt += total[i]
	 # add 0 to force not-null.
	 value = value sprintf(fmt, total[i]+0)
      }
  }

  if (gtcol != NULL) value = value sprintf(fmt, gt)

  if (report) {
     dashes = value
     gsub(/[^\t]+/,"-",dashes)
     print dashes > o_file
  }

  if (trim) {
     sub(/^\t+/,"",value)
     sub(/\t+$/,"",value)
  }

  print value > o_file

  if (report) {
     gsub(/[^\t]+/,"=",value)
     print value > o_file
  }
}

# End of program.
